• ‘’ ⇒ (””) 형태로 변경해준다.
• kotlin에서는 java를 사용하지 않기 때문에, java 대신 jvm으로 바꿔준다.
• 프로젝트에서 spring, jpa를 사용하므로 두개를 추가해준다.

// java
plugins {
	id 'org.springframework.boot' version '2.7.0'
	id 'io.spring.dependency-management' version '1.0.11.RELEASE'
	id 'java'
}

// kotlin
plugins {
	id("org.springframework.boot") version "2.6.7"
	id("io.spring.dependency-management") version "1.0.11.RELEASE"
	kotlin("jvm") version "1.6.21"
	kotlin("plugin.spring") version "1.6.21"
	kotlin("plugin.jpa") version "1.6.21"
}

• java version을 enum 형태로 변경해준다.

// java
group = 'com.fastcampus.kotlinspring'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

// kotlin
group = "com.fastcampus.kotlinspring"
version = "0.0.1-SNAPSHOT"
java.sourceCompatibility = JavaVersion.VERSION_11

• configurations : extendsFrom이 함수 형태로 되어 있어서 그에 맞게 변경해준다.
  • lombok을 사용하지 않을 예정이라 현재 프로젝트에서는 제거해도 큰 문제가 되지 않느다.

// java
configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

// kotlin
configurations {
	compileOnly {
		extendsFrom(configurations.annotationProcessor.get())
	}
}

• repositories 는 동일하다.
• dependencies는 함수형태로 변경해주면 된다.
  • lombok은 dataclass 사용하기 때문에 제거해준다.
  • jackson 모듈을 추가해준다. (기본생성자 제공, serializer, deserializer 제공)
  • jetbrain에서 기본제공하는 의존성인 kotlin-reflect, kotlin-stdlib-jdk8 를 추가해준다. (kotlin 프로젝트에서 거의 필수적으로 사용되는 의존성)

kotlin-reflection 런타임 때 프로그램의 구조를 분석해내는 기법 https://kyyeto.tistory.com/entry/코틀린-코틀린의-리플렉션Reflection

// java
repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'
	runtimeOnly 'com.h2database:h2'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

// kotlin
repositories {
	mavenCentral()
}

dependencies {
	implementation("org.springframework.boot:spring-boot-starter-data-jpa")
	implementation("org.springframework.boot:spring-boot-starter-web")

	implementation("com.fasterxml.jackson.module:jackson-module-kotlin")
	
	implementation("org.jetbrains.kotlin:kotlin-reflect")
	implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8")

	runtimeOnly("com.h2database:h2")
	testImplementation("org.springframework.boot:spring-boot-starter-test")

}

• kotlin 컴파일에 대한 옵션을 넣어준다.

tasks.withType<KotlinCompile> {
	kotlinOptions {
		freeCompilerArgs = listOf("-Xjsr305=strict")
		jvmTarget = "11"
	}
}

• test에 대한 Task는 tasks의 제네릭 형태로 작성해준다.